點(diǎn)擊藍(lán)字關(guān)注【秋葉 Excel】

發(fā)送【7】

免費(fèi)領(lǐng) 1000+篇 Excel 精選教程！

本文作者：小爽

本文編輯：竺蘭

大家好，這里是秋葉編輯部~

在生活中，我們有時(shí)會(huì)對(duì)每天所購(gòu)買的產(chǎn)品做一個(gè)簡(jiǎn)單的記錄。

由于記錄的是一維表，當(dāng)要進(jìn)行數(shù)據(jù)分析的時(shí)候，我們要對(duì)數(shù)據(jù)進(jìn)行匯總操作。

如下圖，我想要知道自己每天購(gòu)買的商品有哪些，對(duì)應(yīng)的匯總有多少，每天都花了多少錢。

所以，問(wèn)題又來(lái)了，如何將左圖轉(zhuǎn)換為右圖呢？

看到這種問(wèn)題，我們的第一反應(yīng)應(yīng)該就是使用函數(shù)了

分步函數(shù)做法

從左表到右表一共三列，那我們就一列列來(lái)做。

▋購(gòu)買日期

由于我們是基于購(gòu)買日期進(jìn)行匯總，所以我們對(duì)購(gòu)買日期進(jìn)行去重操作。

Unique 函數(shù)就是用來(lái)去重的。

在 E2 單元格中輸入函數(shù)公式：

=UNIQUE($C$2:$C$13)

▋購(gòu)買總金額

基于日期按條件進(jìn)行判斷，再對(duì)對(duì)應(yīng)的金額進(jìn)行求和匯總。

抓住關(guān)鍵字，條件+求和。

我們不難想到 Sumif 函數(shù)（Sum 求和+IF 條件）。

Sumif 函數(shù)語(yǔ)法規(guī)則如下：

=SUMIF(條件區(qū)域,條件,求和區(qū)域)

在 G2 單元格中，輸入以下函數(shù)公式，并下拉填充：

=SUMIF($C$2:$C$13,E2,$B$2:$B$13)

▋購(gòu)買明細(xì)

先梳理一下思路步驟。

以 2025/7/1 日期為例

? 基于 2025/7/1，對(duì)數(shù)據(jù)源按照日期進(jìn)行篩選。

Filter 函數(shù)語(yǔ)法規(guī)則：

=FILTER(數(shù)組,包括,[是否包含空])

如下圖所示：

=FILTER($A$2:$B$13,$C$2:$C$13=$E$10)

? 將篩選后的產(chǎn)品名稱進(jìn)行分組求和匯總。

Groupby 函數(shù)語(yǔ)法規(guī)則：

=GROUPBY(行字段，值區(qū)域,匯總方式,[是否包含標(biāo)頭],[是否顯示總計(jì)],[排序方式],[篩選區(qū)域],[相關(guān)方式])

如下圖所示：

=GROUPBY(F12:F14,G12:G14,SUM,,0)

? 利用合并函數(shù)對(duì)數(shù)據(jù)進(jìn)行合并。

Textjoin函數(shù)語(yǔ)法規(guī)則：

=TEXTJOIN(分隔符，是否忽略空值,文本1,文本2....)

觀察數(shù)據(jù)，我們可以發(fā)現(xiàn)分隔符為{"",","}。

對(duì)應(yīng)函數(shù)公式，如下圖所示：

=TEXTJOIN({"",","},,F16#)

接下來(lái)，我們就來(lái)整合上面函數(shù)。

如下圖，輸入公式并下拉填充：

=LET(data,FILTER($A$2:$B$13,$C$2:$C$13=E2),gy_data,GROUPBY(CHOOSECOLS(data,1),CHOOSECOLS(data,2),SUM,,0),TEXTJOIN({"",","},,gy_data))

其中，涉及函數(shù)簡(jiǎn)單介紹。

Let 函數(shù)

Let 函數(shù)是一個(gè)自定義函數(shù)，用于在公式中定義和使用變量。

使用 Let 函數(shù)的好處是，定義變量后方便后續(xù)重復(fù)調(diào)用，這也使得函數(shù)公式變得簡(jiǎn)潔直觀。

有點(diǎn)類似名稱管理器，不過(guò)使用函數(shù)更加靈活。

Let 函數(shù)語(yǔ)法規(guī)則如下：

=LET(名稱1,名稱值1,計(jì)算或名稱2,...)

Choosecols 函數(shù)

Choosecols 函數(shù)能夠取指定區(qū)域的第n列。

Choosecols 函數(shù)的語(yǔ)法規(guī)則如下：

=CHOOSECOLS(數(shù)組,列數(shù)1,[列數(shù)2...])

明白了所需的函數(shù)，函數(shù)公式就不難理解了。

=LET(
    data,FILTER($A$2:$B$13,$C$2:$C$13=E2),
     //對(duì)2025/7/1日期進(jìn)行篩選，獲取篩選后的產(chǎn)品名稱和數(shù)量，數(shù)據(jù)表。

    gy_data,GROUPBY(CHOOSECOLS(data,1),CHOOSECOLS(data,2),SUM,,0),
     //取data數(shù)據(jù)第一列也就是產(chǎn)品名稱進(jìn)行分組，取data第二列也就是數(shù)量進(jìn)行求和。 
    
    TEXTJOIN({"",","},,gy_data)
     //對(duì)分組后匯總的數(shù)據(jù)，進(jìn)行合并。行方向分隔符為空""，列方向分隔符為逗號(hào)。
)

上面我們是函數(shù)分步做的，如果想要函數(shù)公式一步到位呢？

接下來(lái)一起看看。

函數(shù)一步到位

我們先來(lái)看看具體做法。

輸入如下函數(shù)公式：

=LET(
   g,GROUPBY(CHOOSECOLS(A2:C13,3,1),B2:B13,SUM,,0),
   GROUPBY(
      CHOOSECOLS(g,1),      
      HSTACK(CHOOSECOLS(g,2)&CHOOSECOLS(g,3),CHOOSECOLS(g,3)),     
      VSTACK(HSTACK(ARRAYTOTEXT,SUM),{"購(gòu)買明細(xì)","購(gòu)買總金額"}),,0)
 )

其中，涉及函數(shù)簡(jiǎn)單介紹。

Hstack 函數(shù)

Hstack 函數(shù)可以將數(shù)組按照橫向拼接。

=HSTACK(數(shù)組1,數(shù)組2...)

Vstack 函數(shù)

Vstack 函數(shù)可以將數(shù)組按照縱向拼接。

=VSTACK(數(shù)組1,數(shù)組2...)

明白前面分步思路，理解這個(gè)函數(shù)公式也簡(jiǎn)單。

? 先對(duì)日期和產(chǎn)品名稱進(jìn)行分組，變量定義為 g。

? 對(duì)變量 g 的表，進(jìn)行按日期分組匯總。

GROUPBY(
     CHOOSECOLS(g,1),
     //取g的第一列，也就是日期列
     
     HSTACK(CHOOSECOLS(g,2)&CHOOSECOLS(g,3),CHOOSECOLS(g,3)),
     //取產(chǎn)品名稱列和購(gòu)買金額列，橫向拼接作為值區(qū)域
     
     VSTACK(HSTACK(ARRAYTOTEXT,SUM),{"購(gòu)買明細(xì)","購(gòu)買總金額"}),,0)
     //匯總方式

好了，到這里，我們的函數(shù)方法就介紹完了。

現(xiàn)在是 AI 時(shí)代，我們也來(lái)看看它給出的解法，這里我使用 WPS 的靈犀 AI。

靈犀 AI

前面我們基于思考，利用函數(shù)解決了問(wèn)題。

那利用 AI 去解決問(wèn)題，

Q：最關(guān)鍵的是什么?

A：就是你解決問(wèn)題的思考步驟，要跟 AI 說(shuō)。

我將圖片上傳給靈犀 AI。

輸入對(duì)應(yīng)的指令：文件信息+要求步驟+整理過(guò)程+解決方法

最后靈犀 AI 基于我的思路生成 VBA 代碼。

雖然代碼比較長(zhǎng)，但是也解決了問(wèn)題。

最后的話

本文講解的是基于數(shù)據(jù)源，進(jìn)行匯總分析的函數(shù)和 AI 解法：

?分步函數(shù)公式，基于一列列拆解完成結(jié)果。

① Unique 函數(shù)，對(duì)購(gòu)買日期進(jìn)行去重；

② Sumif 函數(shù)，對(duì)購(gòu)買日期篩選后求和；

③ Filter+Groupby+Textjoin，篩選分組合并，對(duì)信息進(jìn)行整合。

?一步函數(shù)公式，兩次分組獲取結(jié)果。

① Groupby，購(gòu)買日期+產(chǎn)品名稱進(jìn)行分組；

② 基于上一層分組數(shù)據(jù)，進(jìn)行購(gòu)買日期分組，最后利用 Function 匯總參數(shù)，得到結(jié)果。

? 要利用 AI 解決問(wèn)題，關(guān)鍵在于思路，不同思路，AI 對(duì)應(yīng)出來(lái)的解決方案不同。

工具會(huì)變，但是我們處理思路不會(huì)變的，無(wú)論是 Excel 還是 AI 都一樣。

如果你也想掌握 AI 新工具，希望能盡快上手……

那我推薦你加入《秋葉 AI 智能辦公 3 天實(shí)戰(zhàn)營(yíng)》，秋葉金牌講師教你學(xué)會(huì)包括飛書(shū)多維表格在內(nèi)的4 大字節(jié)工具（豆包、即夢(mèng)、Coze），帶你快速掌握新工具，提高個(gè)人核心競(jìng)爭(zhēng)力。

《秋葉 AI 智能辦公 3 天實(shí)戰(zhàn)營(yíng)》

課程原價(jià) 99 元

現(xiàn)在僅需 0 元！

秋葉實(shí)戰(zhàn)派老師直播授課

專業(yè)助教隨時(shí)答疑

多種 AI 工具教學(xué)

名額有限，立即掃碼預(yù)約上課

添加微信即可進(jìn)群上課

隨課免費(fèi)領(lǐng)?。?/p>

6 套飛書(shū)多維表格模板

AI 寫(xiě)真主題提示詞手冊(cè)

50+ 秋葉 AI 智能體工具集